[ABAP] SMW0 이용해서 템플렛 다운로드

대량 데이터를 업로드 해야 하는 경우, 우선 사용자가 엑셀 파일에 데이터를 입력하게 한 다음에, 그 데이터를 받아서 BDC나 BAPI로 처리한다. 이때 업로드 양식을 모든 사용자들에게 일관되게 제공해야 하기 때문에, 업로드 프로그램에서 템플렛 양식도 제공한다. 

 

여러 방법이 있을 수도 있겠지만, Web Repository(T-code SMW0)를 많이 이용한다. 

 

1. Web Repository(T-code SMW0)에 템플렛 업로드

 - 저장 파일명 : ZTESTFILE

 

2. Application Bar에 업로드 버튼 생성

 

3. PAI 모듈에 PERFORM TEMPLATE_DOWNLOAD 생성

PROCESS AFTER INPUT.
	MODULE EXIT_0100 AT EXIT-COMMAND.
    MODULE USER_COMMAND_0100.

MODULE USER_COMMAND_0100 INPUT.
  CLEAR GV_UCOMM.
  GV_UCOMM = GV_OKCODE.
  CLEAR GV_OKCODE.

  CASE GV_UCOMM.
    WHEN 'TEMP'.   "GUI Status에 등록한 Function Code
      PERFORM TEMPLATE_DOWNLOAD.
  ENDCASE.
ENDMODULE.

4. PERFORM TEMPLATE_DOWNLOAD 로직 구현

FORM TEMPLATE_DOWNLOAD.
    DATA LV_SAVEPATH TYPE STRING.
    
    "4-1. 저장위치 선택
    PERFORM SET_SAVE_PATH CHANGING LV_SAVEPATH.
    
    "4-2. Web Repository에서 파일 선택 및 저장 
    PERFORM SAVE_TEMPLATE USING LV_SAVEPATH.
ENDFORM.

   4-1. 저장 위치 선택

FORM SET_SAVE_PATH CHANGING PV_SAVEPATH.
  DATA : LV_PATH          TYPE STRING,
         LV_SAVE_FILENAME TYPE STRING.
  DATA(LV_FILENAME) = |Template_| & |{ SY-DATUM }| & |.xlsx|.

  CL_GUI_FRONTEND_SERVICES=>FILE_SAVE_DIALOG(
    EXPORTING
      DEFAULT_FILE_NAME         = LV_FILENAME
      FILE_FILTER               = 'Excel files (*.XLS;*.XLSX)|*.XLSX'
      INITIAL_DIRECTORY         = 'D:\'
    CHANGING
      FILENAME                  = LV_SAVE_FILENAME
      PATH                      = LV_PATH
      FULLPATH                  = PV_SAVEPATH
    EXCEPTIONS
      CNTL_ERROR                = 1                " Control error
      ERROR_NO_GUI              = 2                " No GUI available
      NOT_SUPPORTED_BY_GUI      = 3                " GUI does not support this
      INVALID_DEFAULT_FILE_NAME = 4                " Invalid default file name
      OTHERS                    = 5
  ).
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDFORM.

   4-2. Web Repository에서 파일 선택 및 로컬 PC에 저장

    - FUNCTION 'WWWDATA_IMPORT'랑 FUNCTION 'WWWPARAMS_READ'를 이용해서 MIME 타입으로 데이터를 가져온 다음에, PERFORM 'GUI_DOWNLOAD'를 이용하는 방법도 있다.

    - 어차피 FUNCTION 'DOWNLOAD_WEB_OBJECT'안에서 위 3개의 함수를 이용하고 있다

FORM SAVE_TEMPLATE USING PV_SAVEPATH.

 DATA : 	LS_WWWDATA 	TYPE WWWDATATAB,
    		LV_FILE 	TYPE RLGRAP-FILENAME.
            
 SELECT SINGLE * INTO CORRESPONDING FIELDS OF LS_WWWDATA
   FROM WWWDATA
   WHERE OBJID = 'ZTESTFILE'.	"1번에서 저장한 파일명
   
 CHECK PV_SAVEPATH IS NOT INITIAL.
 "PV_SAVEPATH의 타입은 STRING이고, 함수에 넘겨주는 변수타입은 RLGRAP-FILENAME이기 때문에
 "타입 변환을 위해 아래와 같이 값을 전달해준다.
 LV_FILE = PV_SAVEPATH.  

 CALL FUNCTION 'DOWNLOAD_WEB_OBJECT'
    EXPORTING
      KEY          = WWWDATA_ITEM
      DESTINATION  = LV_FILE.
  
  " 다운로드 받은 뒤에 바로 파일을 실행시키고 싶다면 아래 함수를 사용한다. 
  " 이때, DOCUMENT 파라미터는 STRING 타입이기 때문에 LV_FILE이 아닌 PV_SAVEPATH를 이용한다.
  IF SY-SUBRC = 0.
    CL_GUI_FRONTEND_SERVICES=>EXECUTE(
      EXPORTING
        DOCUMENT               = PV_SAVEPATH      " Path+Name to Document
        OPERATION              = 'OPEN'           " Reserved: Verb for ShellExecute
      EXCEPTIONS
        CNTL_ERROR             = 1       " Control error
        ERROR_NO_GUI           = 2       " No GUI available
        BAD_PARAMETER          = 3       " Incorrect parameter combination
        FILE_NOT_FOUND         = 4       " File not found
        PATH_NOT_FOUND         = 5       " Path not found
        FILE_EXTENSION_UNKNOWN = 6       " Could not find application for specified extension
        ERROR_EXECUTE_FAILED   = 7       " Could not execute application or document
        SYNCHRONOUS_FAILED     = 8       " Cannot Call Application Synchronously
        NOT_SUPPORTED_BY_GUI   = 9       " GUI does not support this
        OTHERS                 = 10
    ).
  ENDIF.
         
ENDFORM.